set terminal svg size 800 600 fname "Times,13"
set output "Estimations of Human Brain Emulation Required Performance.svg"
set notitle
set key reverse Left left at 1993, 10**40 noautotitles box # good chunk of whitespace to put the key in
set datafile separator ","

set logscale y # use a logarithmic scale, for easier visualization of exponential growth
set format y "10^{%T}"
set yrange[10**9:10**45]
set ylabel "Flop/s"

set xrange [1990:2065]
set xlabel "Year"
set xtics 1990,5,2065
set mxtics 5
#set grid # I think it looks better without, but it's a matter of preference

# labels for each of the levels of emulation
set label "Analog network population model" at 2010, 10**14.5 left
set label "Spiking neural network" at 2010, 10**17.5 right
set label "Electrophysiology" at 2035, 10**22.5 right
set label "Metabolome" at 2047, 10**25.5 right
set label "Proteome" at 2050, 10**26.5 right
set label "States of protein complexes" at 2054, 10**27.5 right
set label "Distribution of complexes" at 2064, 10**30.5 right
set label "Stochastic behavior of single molecules" at 2064, 10**42.5 right

set label "Functional Simulation" at 2020, 10**16.5 left
set label "Neural Simulation" at 2030, 10**19.5 left

# best-fit is as of June 2022 list, to two sigfigs
# horizontal lines plotted to represent levels of emulation
# plot of historical TOP500 #1's stored in a .csv
# colors and sizes picked from what I thought was easiest to see
# titles done for one of each type of line, for the key
plot 87000000000.0*(2**((x-1993)/1.2)) lw 6 lc 0 w lines title "Trendline (doubling every 1.2 years)",\
     10**15 ls 3 lt rgb "#0073E6", \
     10**18 ls 3 lt rgb "#0073E6", \
     10**22 ls 3 lt rgb "#0073E6", \
     10**25 ls 3 lt rgb "#0073E6", \
     10**26 ls 3 lt rgb "#0073E6", \
     10**27 ls 3 lt rgb "#0073E6", \
     10**30 ls 3 lt rgb "#0073E6", \
     10**43 ls 3 lt rgb "#0073E6" title "Sandberg, Bostrom estimates (2008)",\
     10**16 ls 2 dt (50,10) lc rgb "#89CE00", \
     10**19 ls 2 dt (50,10) lt rgb "#89CE00" title "Kurzweil estimates (2005)",\
     "TOP500.csv" using 1:2 ls 1 lt rgb "#B51963" pt 7 ps .5 with linespoints title "Fastest Supercomputer (TOP500 #1)"