維基百科

File:Uniaxial.png

原始檔案 （800 × 2,000 像素，檔案大小：26 KB，MIME 類型：image/png）

本圖片是以PNG、GIF或JPEG格式上傳。然而，其中包含的資料或訊息，應該重新建立成可縮放向量圖形（SVG）檔案，以更有效率或更準確的方式儲存。如有可能，請上傳本圖片的SVG格式版本。在上傳之後，請修改維基各姊妹計畫中所有使用舊版圖片的條目（列在圖像連結章節中），替換為新版圖片，並在舊圖片的描述頁中加入{{Vector version available|新圖片名稱.svg}}模板，同時移除本模板。

摘要

Source code

Instructions: on a system with a modern TeTeX or similar installed save the following two files, then run 

mpost uniaxial && pdftex uniaxial

You will then need to use ghostscript or similar to make a raster image out of the pdf.

Source code author: en:user:AndrewKepert

Source code license: GPL

 
本PNG graphic使用MetaPost創作。

原始碼

InfoField

PostScript code

picture pic[];
 pair pt[],pt[]n,pt[]e,pt[]w,pt[]s,pt[]ne,pt[]nw,pt[]se,pt[]sw;
 pair ux,uy,uz;
 path unitcircle; unitcircle=fullcircle scaled 2;
 boolean front[];
 color colour[];
 path p[];
 
 u=16;
 ux=.4*down*u;
 uy=right*2u;
 uz=up*.5u;
 
 transform xyplane[];
 (0,0) transformed xyplane0 = (0,0);
 (1,0) transformed xyplane0 = ux;
 (0,1) transformed xyplane0 = uy;
 for i = -1 step 1/16 until 1:
     xyplane[i]=xyplane[0] shifted (i*uz);
 endfor
 
 theta=10;
 alpha=8;
 
 N:=6;
 
 for i = -1 step .5 until N+1:
     pt[i]   = right rotated  theta        rotated (360i/N) transformed xyplane0;
     front[i]= ypart pt[i] < ypart xyplane0;
     pt[i]e  = right rotated (theta+alpha) rotated (360i/N) transformed xyplane0;
     pt[i]w  = right rotated (theta-alpha) rotated (360i/N) transformed xyplane0;
     pt[i]n  = right rotated  theta        rotated (360i/N) transformed xyplane[.75];
     pt[i]ne = right rotated (theta+alpha) rotated (360i/N) transformed xyplane[.75];
     pt[i]nw = right rotated (theta-alpha) rotated (360i/N) transformed xyplane[.75];
     pt[i]s  = right rotated  theta        rotated (360i/N) transformed xyplane[-.75];
     pt[i]se = right rotated (theta+alpha) rotated (360i/N) transformed xyplane[-.75];
     pt[i]sw = right rotated (theta-alpha) rotated (360i/N) transformed xyplane[-.75];
 endfor
 
 t0=directiontime uz of (unitcircle transformed xyplane0);
 t1=directiontime -uz of (unitcircle transformed xyplane0);
 t2=t0+length unitcircle;
 
 path backface,frontface;
 backface:=(subpath (t0,t1) of unitcircle transformed xyplane[1])
         -- (subpath (t1,t0) of unitcircle transformed xyplane[-1])
         -- cycle;
 frontface:= (subpath (t1,t2) of unitcircle transformed xyplane[1])
         -- (subpath (t2,t1) of unitcircle transformed xyplane[-1])
         -- cycle;
 
 colour0:=(.8,.85,1);
 colour1:=.8[black,colour0];
 colour2:=.6[black,colour1];
 
 def constructribbon(expr delta)=
     % stuff on back face
     pic1:=image( for i = 0 step delta until N-eps: if not front[i]: fill p[i]; fi endfor
         fill (subpath (t0,t1) of unitcircle transformed xyplane[1/16])
         -- (subpath (t1,t0) of unitcircle transformed xyplane[-1/16])
         -- cycle;);
     % stuff on front face
     pic2:=image( for i = 0 step delta until N-eps: if  front[i]: fill p[i]; fi endfor
         fill (subpath (t1,t2) of unitcircle transformed xyplane[1/16])
         -- (subpath (t2,t1) of unitcircle transformed xyplane[-1/16])
         -- cycle;);
     % all of back face
     pic0:=image(fill frontface withcolor colour0;
         fill backface withcolor colour1;
         draw pic1 withcolor colour2);
     fill backface withcolor colour0;
     fill frontface withcolor colour0;
     draw pic1;
     clip pic0 to frontface;
     draw pic0;
     draw pic2;
     draw unitcircle transformed xyplane[1] withpen pencircle scaled 0.2 withcolor colour1;
     draw subpath (t2,t1) of unitcircle transformed xyplane[-1] withpen pencircle scaled 0.2 withcolor colour1;
 enddef;
 
 beginfig(1)
     for i=0 upto N-1:
         p[i]:= pt[i]--pt[i]w--pt[i]ne--pt[i]e--cycle;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(2)
     for i=0 upto N-1:
         p[i]:=  pt[i]w--pt[i]ne--pt[i]se--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(3)
     for i=0 upto N-1:
         p[i]:= pt[i]--pt[i]e--pt[i]n--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(4)
     for i=0 upto N-1:
         %p[i]:=  pt[i]--pt[i]ne--pt[i]e--pt[i]--pt[i]sw--pt[i]w--cycle ;
         p[i]:=          pt[i]ne--pt[i]e--       pt[i]sw--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(5)
     for i=0 upto N-1:
         p[i]:=  pt[i]n--pt[i]e--pt[i]s--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(6)
     for i=0 upto N-1:
         p[i]:=  pt[i]--pt[i]e--pt[i]n--pt[i]w--cycle ;
         p[i+.5]:=  pt[i+.5]--pt[i+.5]e--pt[i+.5]s--pt[i+.5]w--cycle ;
     endfor
     constructribbon(1/2);
 endfig;
 
 beginfig(7)
     for i=0 upto N-1:
         if odd i:
             p[i]:= pt[i]--pt[i]w--pt[i]ne--pt[i]e--cycle;
         else:
             p[i]:= pt[i]--pt[i]w--pt[i]se--pt[i]e--cycle;
         fi
     endfor
     constructribbon(1);
 endfig;
 
 
 bye

Data

\input supp-pdf
 {\tabskip=5pt  \lineskiplimit=5pt  \lineskip=\lineskiplimit
 \halign{\hfil#\hfil&\hfil$\vcenter{\convertMPtoPDF{#}{1}{1}}$\hfil\cr
     $C_6$&uniaxial.1\cr
     $C_{6h}$&uniaxial.2\cr
     $C_{6v}$&uniaxial.3\cr
     $D_6$&uniaxial.4\cr
     $D_{6h}$&uniaxial.5\cr
     $D_{6d}$&uniaxial.6\cr
     $S_6$&uniaxial.7\cr
     }
 }
 \bye

授權條款

我，本作品的著作權持有者，決定用以下授權條款發佈本作品：
GNU head 已授權您依據自由軟體基金會發行的無固定段落、封面文字和封底文字GNU自由文件授權條款1.2版或任意後續版本，對本檔進行複製、傳播和／或修改。該協議的副本列在GNU自由文件授權條款中。
w:zh:創用CC
姓名標示 相同方式分享 		此檔案採用創用CC 姓名標示-相同方式分享 3.0 未在地化版本授權條款。
您可以自由：
  • 分享 – 複製、發佈和傳播本作品
  • 重新修改 – 創作演繹作品
惟需遵照下列條件：
  • 姓名標示 – 您必須指名出正確的製作者，和提供授權條款的連結，以及表示是否有對內容上做出變更。您可以用任何合理的方式來行動，但不得以任何方式表明授權條款是對您許可或是由您所使用。
  • 相同方式分享 – 如果您利用本素材進行再混合、轉換或創作，您必須基於如同原先的相同或兼容的條款，來分布您的貢獻成品。
已新增授權條款標題至此檔案，作為GFDL授權更新的一部份。
w:zh:創用CC
姓名標示 相同方式分享
此檔案採用創用CC 姓名標示-相同方式分享 2.5 通用版、2.0 通用版以及1.0 通用版授權條款。
您可以自由：
  • 分享 – 複製、發佈和傳播本作品
  • 重新修改 – 創作演繹作品
惟需遵照下列條件：
  • 姓名標示 – 您必須指名出正確的製作者，和提供授權條款的連結，以及表示是否有對內容上做出變更。您可以用任何合理的方式來行動，但不得以任何方式表明授權條款是對您許可或是由您所使用。
  • 相同方式分享 – 如果您利用本素材進行再混合、轉換或創作，您必須基於如同原先的相同或兼容的條款，來分布您的貢獻成品。
您可以選擇您需要的授權條款。

說明

添加單行說明來描述出檔案所代表的內容

在此檔案描寫的項目

描繪內容

檔案歷史

點選日期/時間以檢視該時間的檔案版本。

日期/時間縮⁠圖尺寸使用者備⁠註
目前2006年7月5日 (三) 08:28於 2006年7月5日 (三) 08:28 版本的縮圖800 × 2,000（26 KB）AndrewKepert~commonswikiAuthor: user:en:AndrewKepert Toolchain: MetaPost and TeX. Source: will be uploaded Description: Illustration of a typical member of each of 7 infinite families of 3D point groups. Destination: en:Point groups in three dimensions. Permission: GF

下列頁面有用到此檔案：

全域檔案使用狀況

以下其他 wiki 使用了這個檔案：

取自「https://zh.wikipedia.org/wiki/File:Uniaxial.png」